Eğitimler


SimpleAudioPlayer

Gerekli Donanım

  • Arduino Ödeme Kurulu
  • 8 ohm hoparlör veya kulaklık
  • CS CS 4 özellikli SD kartlı Arduino koruması (Ethernet kalkanı gibi)

Harici bir ses yükseltici oluşturmak için bileşenler

  • LM386 (düşük güçlü ses yükseltici)
  • 10 kohm potansiyometre
  • 10 ohm direnç
  • 2 x 10 µF kapasitör
  • 0.05 µF (veya 0.1 µF) kapasitör
  • 250 µF kapasitör

Devre

Kalkan, yuvasında bir mikro-SD kart ile Due'ın üzerine oturur. Kartın kök dizininde "test.wav" adlı bir .wav dosyası var. Basit bir test için, polariteye saygı duyan bir çift kulaklığı doğrudan toprağa ve DAC0'a takabilirsiniz .

Anakarta bir hoparlör bağlamak için, DAC0 pimi ile hoparlör arasına bir amplifikasyon devresi eklediniz . Amplifikasyon devresi hoparlörün sesini artıracaktır. Mevcut birçok ses amplifikatörü vardır, en yaygın olanlarından biri LM386'dır . Aşağıdaki şemada, LM386 ve bir grup bileşen kullanılarak devrenin nasıl oluşturulacağı gösterilmektedir. Vs pinini bağlayan LM386'ya Arduino Due veya 5V harici pilin 5V pininde bulunan +5 V gibi farklı voltaj kaynakları sağlayabilirsiniz. Amplifikatörün kazancı, LM386'nın pim 1 ve 8'ine bağlanan kapasitör tarafından verilir. 10 µF kapasitör ile kazanç 200'e ayarlanır, kapasitör olmadan kazanç 50'dir. Potansiyometre ile amplifikatörün ses seviyesini kontrol edebilirsiniz.
Uyarı : hoparlörü doğrudan Arduino Due pimlerine bağlamayın.

LM386 elektronik şematik

LM386 breadboard üzerine montaj

Ses dosyası

SD karta kaydedilecek Ses dosyası, 44100 Hz, 16 bit stereo kalitesinde .wav biçiminde olmalıdır.

Kod

/*
  Simple Audio Player

 Demonstrates the use of the Audio library for the Arduino Due

 Hardware required :
 * Arduino shield with a SD card on CS4
 * A sound file named "test.wav" in the root directory of the SD card
 * An audio amplifier to connect to the DAC0 and ground
 * A speaker to connect to the audio amplifier

 Original by Massimo Banzi September 20, 2012
 Modified by Scott Fitzgerald October 19, 2012
 Modified by Arturo Guadalupi December 18, 2015

 This example code is in the public domain

 http:egitim.aspx?e=SimpleAudioPlayer

*/

#include <SD.h>
#include <SPI.h>
#include <Audio.h>

void setup() {
  // debug output at 9600 baud
  Serial.begin(9600);

  // setup SD-card
  Serial.print("Initializing SD card...");
  if (!SD.begin(4)) {
    Serial.println(" failed!");
    while(true);
  }
  Serial.println(" done.");
  // hi-speed SPI transfers

  // 44100kHz stereo => 88200 sample rate
  // 100 mSec of prebuffering.
  Audio.begin(88200, 100);
}

void loop() {
  int count = 0;

  // open wave file from sdcard
  File myFile = SD.open("test.wav");
  if (!myFile) {
    // if the file didn't open, print an error and stop
    Serial.println("error opening test.wav");
    while (true);
  }

  const int S = 1024; // Number of samples to read in block
  short buffer[S];

  Serial.print("Playing");
  // until the file is not finished
  while (myFile.available()) {
    // read from the file into buffer
    myFile.read(buffer, sizeof(buffer));

    // Prepare samples
    int volume = 1024;
    Audio.prepare(buffer, S, volume);
    // Feed samples to audio
    Audio.write(buffer, S);

    // Every 100 block print a '.'
    count++;
    if (count == 100) {
      Serial.print(".");
      count = 0;
    }
  }
  myFile.close();

  Serial.println("End of file. Thank you for listening!");
  while (true) ;
}
[Kodu Al]

See Also

Audiolib