Eğitimler


WiFiNINAWiFiChatServer

Gelen iletileri bağlı tüm istemcilere dağıtan basit bir sunucu. Kullanmak için bir terminal penceresi açın, WiFi modülünüzün IP adresine telnet gönderin ve yazın. Gelen metinler bağlı tüm istemcilere gönderilecektir (bir tanesi dahil). Ayrıca, müşterinin girişini Arduino Software (IDE) seri monitörünüzde de görebilirsiniz.

Gerekli Donanım

Devre

WiFi modülü kartınıza entegre edilmiştir ve bu öğreticinin çalışması için herhangi bir özel devreye ihtiyacınız yoktur.

Arduino MKR WiFi 1010
Arduino MKR VIDOR 4000
Arduino UNO WiFi Rev.2


Lütfen dikkat: Bu üç kart, WiFi modülünü iletişim kurmak ve seçmek için özel pinler kullanır, bu nedenle başlık pinlerine bağlı mevcut dijital pinlerin kullanımında herhangi bir kısıtlama yoktur.

Kod

Bu örnek için İnternet'e bağlanan bir 802.11b / g kablosuz ağa erişiminizin olması gerekir. Çizimdeki ağ ayarlarını, belirli ağlarınızın SSID'sine karşılık gelecek şekilde değiştirmeniz gerekecektir.

WPA / WPA2 Kişisel şifreleme kullanan ağlar için SSID ve parolaya ihtiyacınız vardır. Kalkan WPA2 Enterprise şifrelemesi kullanan ağlara bağlanmaz.

WEP ağ parolaları, anahtarlar olarak bilinen onaltılık dizelerdir. WEP ağında 4 farklı anahtar bulunabilir; her tuşa bir "Anahtar Dizini" değeri atanır. WEP şifreli ağlar için SSID'ye, anahtara ve anahtar numarasına ihtiyacınız vardır.

/*
 Chat  Server

 A simple server that distributes any incoming messages to all
 connected clients.  To use telnet to  your device's IP address and type.
 You can see the client's input in the serial monitor as well.

 This example is written for a network using WPA encryption. For
 WEP or WPA, change the Wifi.begin() call accordingly.


 Circuit:
 * Board with NINA module (Arduino MKR WiFi 1010, MKR VIDOR 4000 and UNO WiFi Rev.2)

 created 18 Dec 2009
 by David A. Mellis
 modified 31 May 2012
 by Tom Igoe

 */

#include <SPI.h>
#include <WiFiNINA.h>

#include "arduino_secrets.h"
///////please enter your sensitive data in the Secret tab/arduino_secrets.h
char ssid[] = SECRET_SSID;        // your network SSID (name)
char pass[] = SECRET_PASS;    // your network password (use for WPA, or use as key for WEP)

int keyIndex = 0;            // your network key Index number (needed only for WEP)

int status = WL_IDLE_STATUS;

WiFiServer server(23);

boolean alreadyConnected = false; // whether or not the client was connected previously

void setup() {
  //Initialize serial and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port only
  }

  // check for the WiFi module:
  if (WiFi.status() == WL_NO_MODULE) {
    Serial.println("Communication with WiFi module failed!");
    // don't continue
    while (true);
  }

  String fv = WiFi.firmwareVersion();
  if (fv < WIFI_FIRMWARE_LATEST_VERSION) {
    Serial.println("Please upgrade the firmware");
  }

  // attempt to connect to Wifi network:
  while (status != WL_CONNECTED) {
    Serial.print("Attempting to connect to SSID: ");
    Serial.println(ssid);
    // Connect to WPA/WPA2 network. Change this line if using open or WEP network:
    status = WiFi.begin(ssid, pass);

    // wait 10 seconds for connection:
    delay(10000);
  }

  // start the server:
  server.begin();
  // you're connected now, so print out the status:
  printWifiStatus();
}


void loop() {
  // wait for a new client:
  WiFiClient client = server.available();


  // when the client sends the first byte, say hello:
  if (client) {
    if (!alreadyConnected) {
      // clead out the input buffer:
      client.flush();
      Serial.println("We have a new client");
      client.println("Hello, client!");
      alreadyConnected = true;
    }

    if (client.available() > 0) {
      // read the bytes incoming from the client:
      char thisChar = client.read();
      // echo the bytes back to the client:
      server.write(thisChar);
      // echo the bytes to the server as well:
      Serial.write(thisChar);
    }
  }
}


void printWifiStatus() {
  // print the SSID of the network you're attached to:
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  // print your board's IP address:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");
  Serial.println(ip);

  // print the received signal strength:
  long rssi = WiFi.RSSI();
  Serial.print("signal strength (RSSI):");
  Serial.print(rssi);
  Serial.println(" dBm");
}
[Kodu Al]

See Also